a7d0c21033
Inside the linker script, insert the code for DWARF debug info sections. This may help GDB'ing a Uml binary. Actually, it seems that ld is able to guess what I added correctly, but normal linker scripts include this section so it should be correct anyway adding it. On request by Sam Ravnborg <sam@ravnborg.org>, I've added it to asm-generic/vmlinux.lds.s. I've also moved there the stabs debug section, used the new macro in i386 linker script and added DWARF debug section to that. In the truth, I've not been able to verify the difference in GDB behaviour after this change (I've seen large improvements with another patch). This may depend on my binutils version, older one may have worse defaults. However, this section is present in normal linker script, so add it at least for the sake of cleanness. Signed-off-by: Paolo 'Blaisorblade' Giarrusso <blaisorblade@yahoo.it> Acked-by: Sam Ravnborg <sam@ravnborg.org> Signed-off-by: Linus Torvalds <torvalds@osdl.org>
102 lines
2 KiB
ArmAsm
102 lines
2 KiB
ArmAsm
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
OUTPUT_FORMAT(ELF_FORMAT)
|
|
OUTPUT_ARCH(ELF_ARCH)
|
|
ENTRY(_start)
|
|
jiffies = jiffies_64;
|
|
|
|
SECTIONS
|
|
{
|
|
/*This must contain the right address - not quite the default ELF one.*/
|
|
PROVIDE (__executable_start = START);
|
|
. = START + SIZEOF_HEADERS;
|
|
|
|
/* Used in arch/um/kernel/mem.c. Any memory between START and __binary_start
|
|
* is remapped.*/
|
|
__binary_start = .;
|
|
|
|
#ifdef MODE_TT
|
|
.remap_data : { UNMAP_PATH (.data .bss) }
|
|
.remap : { UNMAP_PATH (.text) }
|
|
|
|
. = ALIGN(4096); /* Init code and data */
|
|
#endif
|
|
|
|
_stext = .;
|
|
__init_begin = .;
|
|
.init.text : {
|
|
_sinittext = .;
|
|
*(.init.text)
|
|
_einittext = .;
|
|
}
|
|
. = ALIGN(4096);
|
|
|
|
.text :
|
|
{
|
|
*(.text)
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
*(.fixup)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.gnu.linkonce.t*)
|
|
|
|
. = ALIGN(4096);
|
|
__syscall_stub_start = .;
|
|
*(.__syscall_stub*)
|
|
__syscall_stub_end = .;
|
|
. = ALIGN(4096);
|
|
}
|
|
|
|
#include "asm/common.lds.S"
|
|
|
|
init.data : { *(init.data) }
|
|
.data :
|
|
{
|
|
. = ALIGN(KERNEL_STACK_SIZE); /* init_task */
|
|
*(.data.init_task)
|
|
*(.data)
|
|
*(.gnu.linkonce.d*)
|
|
CONSTRUCTORS
|
|
}
|
|
.data1 : { *(.data1) }
|
|
.ctors :
|
|
{
|
|
*(.ctors)
|
|
}
|
|
.dtors :
|
|
{
|
|
*(.dtors)
|
|
}
|
|
|
|
.got : { *(.got.plt) *(.got) }
|
|
.dynamic : { *(.dynamic) }
|
|
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
|
|
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata : { *(.sdata) }
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
. = ALIGN(0x1000);
|
|
.sbss :
|
|
{
|
|
__bss_start = .;
|
|
PROVIDE(_bss_start = .);
|
|
*(.sbss)
|
|
*(.scommon)
|
|
}
|
|
.bss :
|
|
{
|
|
*(.dynbss)
|
|
*(.bss)
|
|
*(COMMON)
|
|
}
|
|
_end = .;
|
|
PROVIDE (end = .);
|
|
|
|
STABS_DEBUG
|
|
|
|
DWARF_DEBUG
|
|
}
|