969de0988b
Commitbe7635e728("arch, ftrace: for KASAN put hard/soft IRQ entries into separate sections") added a new linker section, SOFTIRQENTRY_TEXT, to the linker scripts for most architectures. It didn't add it to any of the linker scripts for the m68k architecture. This was not really a problem because it is only defined if either of CONFIG_FUNCTION_GRAPH_TRACER or CONFIG_KASAN are enabled - which can never be true for m68k. However commit229a718605("irq: Make the irqentry text section unconditional") means that SOFTIRQENTRY_TEXT is now always defined. So on m68k we now end up with a separate ELF section for .softirqentry.text instead of it being part of the .text section. On some m68k targets in some configurations this can also cause a fatal link error: LD vmlinux /usr/local/bin/../m68k-uclinux/bin/ld.real: section .softirqentry.text loaded at [0000000010de10c0,0000000010de12dd] overlaps section .rodata loaded at [0000000010de10c0,0000000010e0fd67] To fix add in the missing SOFTIRQENTRY_TEXT section into the m68k linker scripts. I noticed that m68k is also missing the IRQENTRY_TEXT section, so this patch also adds an entry for that too. Signed-off-by: Greg Ungerer <gerg@linux-m68k.org>
95 lines
1.5 KiB
Text
95 lines
1.5 KiB
Text
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* vmlinux.lds.S -- master linker script for m68knommu arch
|
|
*
|
|
* (C) Copyright 2002-2012, Greg Ungerer <gerg@snapgear.com>
|
|
*
|
|
* This linker script is equipped to build either ROM loaded or RAM
|
|
* run kernels.
|
|
*/
|
|
|
|
#if defined(CONFIG_RAMKERNEL)
|
|
#define KTEXT_ADDR CONFIG_KERNELBASE
|
|
#endif
|
|
#if defined(CONFIG_ROMKERNEL)
|
|
#define KTEXT_ADDR CONFIG_ROMSTART
|
|
#define KDATA_ADDR CONFIG_KERNELBASE
|
|
#define LOAD_OFFSET KDATA_ADDR + (ADDR(.text) + SIZEOF(.text))
|
|
#endif
|
|
|
|
#include <asm/page.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
OUTPUT_ARCH(m68k)
|
|
ENTRY(_start)
|
|
|
|
jiffies = jiffies_64 + 4;
|
|
|
|
SECTIONS {
|
|
|
|
#ifdef CONFIG_ROMVEC
|
|
. = CONFIG_ROMVEC;
|
|
.romvec : {
|
|
__rom_start = .;
|
|
_romvec = .;
|
|
*(.romvec)
|
|
*(.data..initvect)
|
|
}
|
|
#endif
|
|
|
|
. = KTEXT_ADDR;
|
|
|
|
_text = .;
|
|
_stext = .;
|
|
.text : {
|
|
HEAD_TEXT
|
|
TEXT_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
SCHED_TEXT
|
|
CPUIDLE_TEXT
|
|
LOCK_TEXT
|
|
*(.fixup)
|
|
. = ALIGN(16);
|
|
}
|
|
_etext = .;
|
|
|
|
#ifdef KDATA_ADDR
|
|
. = KDATA_ADDR;
|
|
#endif
|
|
|
|
_sdata = .;
|
|
RO_DATA_SECTION(PAGE_SIZE)
|
|
RW_DATA_SECTION(16, PAGE_SIZE, THREAD_SIZE)
|
|
_edata = .;
|
|
|
|
EXCEPTION_TABLE(16)
|
|
NOTES
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_begin = .;
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
INIT_DATA_SECTION(16)
|
|
PERCPU_SECTION(16)
|
|
.m68k_fixup : {
|
|
__start_fixup = .;
|
|
*(.m68k_fixup)
|
|
__stop_fixup = .;
|
|
}
|
|
.init.data : {
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
}
|
|
|
|
BSS_SECTION(0, 0, 0)
|
|
|
|
_end = .;
|
|
|
|
STABS_DEBUG
|
|
.comment 0 : { *(.comment) }
|
|
|
|
/* Sections to be discarded */
|
|
DISCARDS
|
|
}
|
|
|