a2d063ac21
A new utility function (core_kernel_data()) is used to determine if a passed in address is part of core kernel data or not. It may or may not return true for RO data, but this utility must work for RW data. Thus both _sdata and _edata must be defined and continuous, without .init sections that may later be freed and replaced by volatile memory (memory that can be freed). This utility function is used to determine if data is safe from ever being freed. Thus it should return true for all RW global data that is not in a module or has been allocated, or false otherwise. Also change core_kernel_data() back to the more precise _sdata condition and document the function. Signed-off-by: Steven Rostedt <rostedt@goodmis.org> Acked-by: Ralf Baechle <ralf@linux-mips.org> Acked-by: Hirokazu Takata <takata@linux-m32r.org> Cc: Richard Henderson <rth@twiddle.net> Cc: Ivan Kokshaysky <ink@jurassic.park.msu.ru> Cc: Matt Turner <mattst88@gmail.com> Cc: Geert Uytterhoeven <geert@linux-m68k.org> Cc: Roman Zippel <zippel@linux-m68k.org> Cc: linux-m68k@lists.linux-m68k.org Cc: Kyle McMartin <kyle@mcmartin.ca> Cc: Helge Deller <deller@gmx.de> Cc: JamesE.J.Bottomley <jejb@parisc-linux.org> Link: http://lkml.kernel.org/r/1305855298.1465.19.camel@gandalf.stny.rr.com Signed-off-by: Ingo Molnar <mingo@elte.hu> ---- arch/alpha/kernel/vmlinux.lds.S | 1 + arch/m32r/kernel/vmlinux.lds.S | 1 + arch/m68k/kernel/vmlinux-std.lds | 2 ++ arch/m68k/kernel/vmlinux-sun3.lds | 1 + arch/mips/kernel/vmlinux.lds.S | 1 + arch/parisc/kernel/vmlinux.lds.S | 3 +++ kernel/extable.c | 12 +++++++++++- 7 files changed, 20 insertions(+), 1 deletion(-)
165 lines
3.2 KiB
ArmAsm
165 lines
3.2 KiB
ArmAsm
#include <asm/asm-offsets.h>
|
|
#include <asm/page.h>
|
|
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
#undef mips
|
|
#define mips mips
|
|
OUTPUT_ARCH(mips)
|
|
ENTRY(kernel_entry)
|
|
PHDRS {
|
|
text PT_LOAD FLAGS(7); /* RWX */
|
|
note PT_NOTE FLAGS(4); /* R__ */
|
|
}
|
|
|
|
#ifdef CONFIG_32BIT
|
|
#ifdef CONFIG_CPU_LITTLE_ENDIAN
|
|
jiffies = jiffies_64;
|
|
#else
|
|
jiffies = jiffies_64 + 4;
|
|
#endif
|
|
#else
|
|
jiffies = jiffies_64;
|
|
#endif
|
|
|
|
SECTIONS
|
|
{
|
|
#ifdef CONFIG_BOOT_ELF64
|
|
/* Read-only sections, merged into text segment: */
|
|
/* . = 0xc000000000000000; */
|
|
|
|
/* This is the value for an Origin kernel, taken from an IRIX kernel. */
|
|
/* . = 0xc00000000001c000; */
|
|
|
|
/* Set the vaddr for the text segment to a value
|
|
* >= 0xa800 0000 0001 9000 if no symmon is going to configured
|
|
* >= 0xa800 0000 0030 0000 otherwise
|
|
*/
|
|
|
|
/* . = 0xa800000000300000; */
|
|
. = 0xffffffff80300000;
|
|
#endif
|
|
. = VMLINUX_LOAD_ADDRESS;
|
|
/* read-only */
|
|
_text = .; /* Text and read-only data */
|
|
.text : {
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
KPROBES_TEXT
|
|
IRQENTRY_TEXT
|
|
*(.text.*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
} :text = 0
|
|
_etext = .; /* End of text section */
|
|
|
|
EXCEPTION_TABLE(16)
|
|
|
|
/* Exception table for data bus errors */
|
|
__dbe_table : {
|
|
__start___dbe_table = .;
|
|
*(__dbe_table)
|
|
__stop___dbe_table = .;
|
|
}
|
|
|
|
NOTES :text :note
|
|
.dummy : { *(.dummy) } :text
|
|
|
|
_sdata = .; /* Start of data section */
|
|
RODATA
|
|
|
|
/* writeable */
|
|
_sdata = .; /* Start of data section */
|
|
.data : { /* Data */
|
|
. = . + DATAOFFSET; /* for CONFIG_MAPPED_KERNEL */
|
|
|
|
INIT_TASK_DATA(PAGE_SIZE)
|
|
NOSAVE_DATA
|
|
CACHELINE_ALIGNED_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
|
|
READ_MOSTLY_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
|
|
DATA_DATA
|
|
CONSTRUCTORS
|
|
}
|
|
_gp = . + 0x8000;
|
|
.lit8 : {
|
|
*(.lit8)
|
|
}
|
|
.lit4 : {
|
|
*(.lit4)
|
|
}
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata : {
|
|
*(.sdata)
|
|
}
|
|
_edata = .; /* End of data section */
|
|
|
|
/* will be freed after init */
|
|
. = ALIGN(PAGE_SIZE); /* Init code and data */
|
|
__init_begin = .;
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
INIT_DATA_SECTION(16)
|
|
|
|
. = ALIGN(4);
|
|
.mips.machines.init : AT(ADDR(.mips.machines.init) - LOAD_OFFSET) {
|
|
__mips_machines_start = .;
|
|
*(.mips.machines.init)
|
|
__mips_machines_end = .;
|
|
}
|
|
|
|
/* .exit.text is discarded at runtime, not link time, to deal with
|
|
* references from .rodata
|
|
*/
|
|
.exit.text : {
|
|
EXIT_TEXT
|
|
}
|
|
.exit.data : {
|
|
EXIT_DATA
|
|
}
|
|
|
|
PERCPU(1 << CONFIG_MIPS_L1_CACHE_SHIFT, PAGE_SIZE)
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
/* freed after init ends here */
|
|
|
|
BSS_SECTION(0, 0, 0)
|
|
|
|
_end = . ;
|
|
|
|
/* These mark the ABI of the kernel for debuggers. */
|
|
.mdebug.abi32 : {
|
|
KEEP(*(.mdebug.abi32))
|
|
}
|
|
.mdebug.abi64 : {
|
|
KEEP(*(.mdebug.abi64))
|
|
}
|
|
|
|
/* This is the MIPS specific mdebug section. */
|
|
.mdebug : {
|
|
*(.mdebug)
|
|
}
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
|
|
/* These must appear regardless of . */
|
|
.gptab.sdata : {
|
|
*(.gptab.data)
|
|
*(.gptab.sdata)
|
|
}
|
|
.gptab.sbss : {
|
|
*(.gptab.bss)
|
|
*(.gptab.sbss)
|
|
}
|
|
|
|
/* Sections to be discarded */
|
|
DISCARDS
|
|
/DISCARD/ : {
|
|
/* ABI crap starts here */
|
|
*(.MIPS.options)
|
|
*(.options)
|
|
*(.pdr)
|
|
*(.reginfo)
|
|
}
|
|
}
|