b64bb1d758
Changes include: - Support for alternative instruction patching from Andre - seccomp from Akashi - Some AArch32 instruction emulation, required by the Android folks - Optimisations for exception entry/exit code, cmpxchg, pcpu atomics - mmu_gather range calculations moved into core code - EFI updates from Ard, including long-awaited SMBIOS support - /proc/cpuinfo fixes to align with the format used by arch/arm/ - A few non-critical fixes across the architecture -----BEGIN PGP SIGNATURE----- Version: GnuPG v1 iQEcBAABCgAGBQJUhbSAAAoJELescNyEwWM07PQH/AolxqOJTTg8TKe2wvRC+DwY R98bcECMwhXvwep1KhTBew7z7NRzXJvVVs+EePSpXWX2+KK2aWN4L50rAb9ow4ty PZ5EFw564g3rUpc7cbqIrM/lasiYWuIWw/BL+wccOm3mWbZfokBB2t0tn/2rVv0K 5tf2VCLLxgiFJPLuYk61uH7Nshvv5uJ6ODwdXjbrH+Mfl6xsaiKv17ZrfP4D/M4o hrLoXxVTuuWj3sy/lBJv8vbTbKbQ6BGl9JQhBZGZHeKOdvX7UnbKH4N5vWLUFZya QYO92AK1xGolu8a9bEfzrmxn0zXeAHgFTnRwtDCekOvy0kTR9MRIqXASXKO3ZEU= =rnFX -----END PGP SIGNATURE----- Merge tag 'arm64-upstream' of git://git.kernel.org/pub/scm/linux/kernel/git/arm64/linux Pull arm64 updates from Will Deacon: "Here's the usual mixed bag of arm64 updates, also including some related EFI changes (Acked by Matt) and the MMU gather range cleanup (Acked by you). Changes include: - support for alternative instruction patching from Andre - seccomp from Akashi - some AArch32 instruction emulation, required by the Android folks - optimisations for exception entry/exit code, cmpxchg, pcpu atomics - mmu_gather range calculations moved into core code - EFI updates from Ard, including long-awaited SMBIOS support - /proc/cpuinfo fixes to align with the format used by arch/arm/ - a few non-critical fixes across the architecture" * tag 'arm64-upstream' of git://git.kernel.org/pub/scm/linux/kernel/git/arm64/linux: (70 commits) arm64: remove the unnecessary arm64_swiotlb_init() arm64: add module support for alternatives fixups arm64: perf: Prevent wraparound during overflow arm64/include/asm: Fixed a warning about 'struct pt_regs' arm64: Provide a namespace to NCAPS arm64: bpf: lift restriction on last instruction arm64: Implement support for read-mostly sections arm64: compat: align cacheflush syscall with arch/arm arm64: add seccomp support arm64: add SIGSYS siginfo for compat task arm64: add seccomp syscall for compat task asm-generic: add generic seccomp.h for secure computing mode 1 arm64: ptrace: allow tracer to skip a system call arm64: ptrace: add NT_ARM_SYSTEM_CALL regset arm64: Move some head.text functions to executable section arm64: jump labels: NOP out NOP -> NOP replacement arm64: add support to dump the kernel page tables arm64: Add FIX_HOLE to permanent fixed addresses arm64: alternatives: fix pr_fmt string for consistency arm64: vmlinux.lds.S: don't discard .exit.* sections at link-time ...
124 lines
2.9 KiB
ArmAsm
124 lines
2.9 KiB
ArmAsm
/*
|
|
* EFI entry point.
|
|
*
|
|
* Copyright (C) 2013, 2014 Red Hat, Inc.
|
|
* Author: Mark Salter <msalter@redhat.com>
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <linux/init.h>
|
|
|
|
#include <asm/assembler.h>
|
|
|
|
#define EFI_LOAD_ERROR 0x8000000000000001
|
|
|
|
__INIT
|
|
|
|
/*
|
|
* We arrive here from the EFI boot manager with:
|
|
*
|
|
* * CPU in little-endian mode
|
|
* * MMU on with identity-mapped RAM
|
|
* * Icache and Dcache on
|
|
*
|
|
* We will most likely be running from some place other than where
|
|
* we want to be. The kernel image wants to be placed at TEXT_OFFSET
|
|
* from start of RAM.
|
|
*/
|
|
ENTRY(efi_stub_entry)
|
|
/*
|
|
* Create a stack frame to save FP/LR with extra space
|
|
* for image_addr variable passed to efi_entry().
|
|
*/
|
|
stp x29, x30, [sp, #-32]!
|
|
|
|
/*
|
|
* Call efi_entry to do the real work.
|
|
* x0 and x1 are already set up by firmware. Current runtime
|
|
* address of image is calculated and passed via *image_addr.
|
|
*
|
|
* unsigned long efi_entry(void *handle,
|
|
* efi_system_table_t *sys_table,
|
|
* unsigned long *image_addr) ;
|
|
*/
|
|
adrp x8, _text
|
|
add x8, x8, #:lo12:_text
|
|
add x2, sp, 16
|
|
str x8, [x2]
|
|
bl efi_entry
|
|
cmn x0, #1
|
|
b.eq efi_load_fail
|
|
|
|
/*
|
|
* efi_entry() will have copied the kernel image if necessary and we
|
|
* return here with device tree address in x0 and the kernel entry
|
|
* point stored at *image_addr. Save those values in registers which
|
|
* are callee preserved.
|
|
*/
|
|
mov x20, x0 // DTB address
|
|
ldr x0, [sp, #16] // relocated _text address
|
|
ldr x21, =stext_offset
|
|
add x21, x0, x21
|
|
|
|
/*
|
|
* Calculate size of the kernel Image (same for original and copy).
|
|
*/
|
|
adrp x1, _text
|
|
add x1, x1, #:lo12:_text
|
|
adrp x2, _edata
|
|
add x2, x2, #:lo12:_edata
|
|
sub x1, x2, x1
|
|
|
|
/*
|
|
* Flush the copied Image to the PoC, and ensure it is not shadowed by
|
|
* stale icache entries from before relocation.
|
|
*/
|
|
bl __flush_dcache_area
|
|
ic ialluis
|
|
|
|
/*
|
|
* Ensure that the rest of this function (in the original Image) is
|
|
* visible when the caches are disabled. The I-cache can't have stale
|
|
* entries for the VA range of the current image, so no maintenance is
|
|
* necessary.
|
|
*/
|
|
adr x0, efi_stub_entry
|
|
adr x1, efi_stub_entry_end
|
|
sub x1, x1, x0
|
|
bl __flush_dcache_area
|
|
|
|
/* Turn off Dcache and MMU */
|
|
mrs x0, CurrentEL
|
|
cmp x0, #CurrentEL_EL2
|
|
b.ne 1f
|
|
mrs x0, sctlr_el2
|
|
bic x0, x0, #1 << 0 // clear SCTLR.M
|
|
bic x0, x0, #1 << 2 // clear SCTLR.C
|
|
msr sctlr_el2, x0
|
|
isb
|
|
b 2f
|
|
1:
|
|
mrs x0, sctlr_el1
|
|
bic x0, x0, #1 << 0 // clear SCTLR.M
|
|
bic x0, x0, #1 << 2 // clear SCTLR.C
|
|
msr sctlr_el1, x0
|
|
isb
|
|
2:
|
|
/* Jump to kernel entry point */
|
|
mov x0, x20
|
|
mov x1, xzr
|
|
mov x2, xzr
|
|
mov x3, xzr
|
|
br x21
|
|
|
|
efi_load_fail:
|
|
mov x0, #EFI_LOAD_ERROR
|
|
ldp x29, x30, [sp], #32
|
|
ret
|
|
|
|
efi_stub_entry_end:
|
|
ENDPROC(efi_stub_entry)
|