1c30385ae4
1) Cleanup an ugly hyper-nested code in Makefile (now only the arith.
expression is passed through the host bash).
2) Fix a problem with GCC 2.95: according to a report from Raphael Bossek,
.remap_data : { arch/um/sys-SUBARCH/unmap_fin.o (.data .bss) } is expanded
into: .remap_data : { arch/um/sys-i386 /unmap_fin.o (.data .bss) }
(because I didn't use ## to join the two tokens), thus stopping linking. Pass
the whole path from the Makefile as a simple and nice fix.
Signed-off-by: Paolo 'Blaisorblade' Giarrusso <blaisorblade@yahoo.it>
Cc: Raphael Bossek <raphael.bossek@gmx.de>
Cc: Jeff Dike <jdike@addtoit.com>
Signed-off-by: Andrew Morton <akpm@osdl.org>
Signed-off-by: Linus Torvalds <torvalds@osdl.org>
106 lines
2.2 KiB
ArmAsm
106 lines
2.2 KiB
ArmAsm
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
OUTPUT_FORMAT(ELF_FORMAT)
|
|
OUTPUT_ARCH(ELF_ARCH)
|
|
ENTRY(_start)
|
|
jiffies = jiffies_64;
|
|
|
|
SECTIONS
|
|
{
|
|
/*This must contain the right address - not quite the default ELF one.*/
|
|
PROVIDE (__executable_start = START);
|
|
. = START + SIZEOF_HEADERS;
|
|
|
|
/* Used in arch/um/kernel/mem.c. Any memory between START and __binary_start
|
|
* is remapped.*/
|
|
__binary_start = .;
|
|
|
|
#ifdef MODE_TT
|
|
.remap_data : { UNMAP_PATH (.data .bss) }
|
|
.remap : { UNMAP_PATH (.text) }
|
|
|
|
. = ALIGN(4096); /* Init code and data */
|
|
#endif
|
|
|
|
_stext = .;
|
|
__init_begin = .;
|
|
.init.text : {
|
|
_sinittext = .;
|
|
*(.init.text)
|
|
_einittext = .;
|
|
}
|
|
. = ALIGN(4096);
|
|
|
|
.text :
|
|
{
|
|
*(.text)
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
*(.fixup)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.gnu.linkonce.t*)
|
|
|
|
. = ALIGN(4096);
|
|
__syscall_stub_start = .;
|
|
*(.__syscall_stub*)
|
|
__syscall_stub_end = .;
|
|
. = ALIGN(4096);
|
|
}
|
|
|
|
#include "asm/common.lds.S"
|
|
|
|
init.data : { *(init.data) }
|
|
.data :
|
|
{
|
|
. = ALIGN(KERNEL_STACK_SIZE); /* init_task */
|
|
*(.data.init_task)
|
|
*(.data)
|
|
*(.gnu.linkonce.d*)
|
|
CONSTRUCTORS
|
|
}
|
|
.data1 : { *(.data1) }
|
|
.ctors :
|
|
{
|
|
*(.ctors)
|
|
}
|
|
.dtors :
|
|
{
|
|
*(.dtors)
|
|
}
|
|
|
|
.got : { *(.got.plt) *(.got) }
|
|
.dynamic : { *(.dynamic) }
|
|
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
|
|
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata : { *(.sdata) }
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
. = ALIGN(0x1000);
|
|
.sbss :
|
|
{
|
|
__bss_start = .;
|
|
PROVIDE(_bss_start = .);
|
|
*(.sbss)
|
|
*(.scommon)
|
|
}
|
|
.bss :
|
|
{
|
|
*(.dynbss)
|
|
*(.bss)
|
|
*(COMMON)
|
|
}
|
|
_end = . ;
|
|
PROVIDE (end = .);
|
|
/* Stabs debugging sections. */
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
}
|